Input Polling / Input Controller

One of the basic features a game needs is the control of inputs. And it is not done with just checking which key is pressed or where the mouse is. Most games need much more than just reacting on clicks.

Imagine a combat game, where you allow users to have key-combos for special attacks and animations.

Therefor we provide the easy to use TGorillaInputController component to access keyboard, mouse and gamepad feedbacks. Also in combination!

A HotKey is a combination of inputs that are simultanously active. Each HotKey can manage inputs from keyboard, mouse and/or gamepad. An input is a hardware message:

• For keyboards, inputs are the pressed keys
• For mouse, inputs are pressed mouse buttons
• For gamepad, inputs are pressed gamepad buttons

You can define up to 4 inputs per device. Which means you can handle up to 12 simultanously active input messages.

In case you define an input in two different HotKeys, the system will detect the more important Hotkey. The importance is defined by the number of set inputs.

If a HotKey was detected, the controller will call the OnTriggered event and/or an attached TAction instance.

You are allowed to setup your HotKeys at design- and at runtime.

Because HotKeys were implemented by the TCollection component of Delphi, you can setup your combinations at design time.

1. Drag a TGorillaInputController component onto your form and doubleclick the “HotKeys” property.
2. In the Delphi Collection-Editor you can now add a new TGorillaHotKeyItem.
3. Type in a unique name to identify your hotkey, create a OnTriggered event or attach a TAction component to it.
4. In the next step we should add the input combination by double clicking the “Combinations” property.
5. Here we can now add a new TGorillaHotKeyInputItem.
6. In the item select the “Kind” of device.
7. and add the message input code
8. Repeat it for any further inputs you wish to combine.

uses
  Gorilla.Controller.Input,
  Gorilla.Controller.Input.Consts;
 
procedure TForm1.DoOnHotKey(const AItem : TGorillaHotKeyItem; const ACurrentInput : TGorillaHotKeyRaw);
begin
  DebugOutput(Format('>>> HotKey: %s <<< === %s', [AItem.DisplayName, ACurrentInput.ToString()]));
end;
 
var 
  FInput : TGorillaInputController;
  LHotKey : TGorillaHotKeyItem;
 
  [...]
 
  FInput := TGorillaInputController.Create(Self);
 
  LHotKey := FInput.AddHotKey('TEST1');
  LHotKey.OnTriggered := DoOnHotKey;
  LHotKey.AddInput(TGorillaInputDeviceType.Keyboard, Ord(GORILLA_INPUT_KEY_ALT));
  LHotKey.AddInput(TGorillaInputDeviceType.Keyboard, Ord(GORILLA_INPUT_KEY_C));
  LHotKey.AddInput(TGorillaInputDeviceType.Keyboard, Ord(GORILLA_INPUT_KEY_RETURN));

Besides the HotKey settings the component supports persistent/continuously messages. A persistent message is a continuously notified message from the system and not a temporary message like a click or key-press.

Supported persistent messages are:

You can request those messages at runtime, like in the following code:

var LMPos  : TPoint;
    LMsg   : TGorillaInputMessage;
begin
  // request latest mouse position
  if FInput.GetPersistentMessage(TGorillaInputDeviceType.Mouse, GORILLA_INPUT_MOUSE_POSITION, LMsg) then
  begin
    LMPos := LMsg.Data.AsType<TPoint>();
  end
  else LMPos := TPoint.Zero;
 
  // show mouse position in form caption
  Self.Caption := Format('Gorilla 3D - Mouse: [%d;%d]', [LMPos.X, LMPos.Y]);

All available InputCodes are defined in the Gorilla.Controller.Input.Consts unit.

HotKeys are a nice feature, but only work for simultaneous inputs.

Imagine you build a combat game, where attacks or defences are represented by input-combos. For example a user needs to press Button A, then Button B and then Button X to do roundhouse kick. Therefor sequences come in place. Sequences are a descriptive plan of hotkeys, where the order is important.

So Sequence #1

Button A + Button B + Button X

is not the same like

Button B + Button A + Button X

procedure TForm1.DoOnSequence(const ASequence : TGorillaInputSequenceItem);
begin
  DebugOutput(Format('>>> Sequence: %s <<<', [ASequence.DisplayName]));
end;
 
[...]
 
var LSequence: TGorillaInputSequenceItem;
    LSeq1HK1, LSeq1HK2, LSeq1HK3 : TGorillaHotKeyItem;
 
  [...]
 
  // create hotkey #1
  LSeq1HK1 := FInput.AddHotKey('STRIDE LEFT');
  LSeq1HK1.AddInput(TGorillaInputDeviceType.Keyboard, Ord(GORILLA_INPUT_KEY_A));
 
  // create hotkey #2
  LSeq1HK2 := FInput.AddHotKey('FORWARD');
  LSeq1HK2.AddInput(TGorillaInputDeviceType.Keyboard, Ord(GORILLA_INPUT_KEY_W));
 
  // create hotkey #3
  LSeq1HK3 := FInput.AddHotKey('STRIDE RIGHT');
  LSeq1HK3.AddInput(TGorillaInputDeviceType.Keyboard, Ord(GORILLA_INPUT_KEY_D));
 
  // create the sequence and add the relevant hotkeys
  LSequence := FInput.AddSequence('TEST SEQUENCE', [LSeq1HK1, LSeq1HK2, LSeq1HK3]);
  LSequence.OnTriggered := DoOnSequence;