Character Controlling

For most games or apps a character / camera controlling is necessary to move in 3D space. This section handles firstperson- and thirdperson character controlling and all expandable components. The framework makes it very easy to implement such behaviour. Without huge coding you can setup everything at design-time.

The TGorillaCharacterController is the basis class for TGorillaFirstPersonController and TGorillaThirdPersonController, but should not be used directly, because it's only an abstraction layer for shared functionality.

All character controllers receive inputs from a TGorillaInputController instance. By those inputs a linked camera component will be moved or users are allowed to interact with your game.

Because we've linked an input controller to the character controller, we have to define hotkeys to react on.

In short this means: if the input controller detects a hotkey, it will forward the event to the character controller. And then the character controller will react on the hotkey event by a specific operation, like moving forward or shooting.

By default the character controllery already defines standardized hotkeys, like W-A-S-D for movement. But you're allowed to overwrite those hotkeys by your own.

Predefined input hotkeys by the TGorillaCharacterController class are:

Remark: All available input codes are defined in Gorilla.Controller.Input.Consts.pas.

For individual treatment you can disable or overwrite those predefined hotkeys. The basic character controller component catches all input events, handles them and throws back user-friendly events.

Because movement is not always equal in every game, we implemented some easy-to-use property to control it.

The TGorillaFirstPersonController controls movement of a linked camera component in its basic settings. But you're allowed to add sub controls like a TGorillaModel to display arms or weapons as known in typical ego shooter games.

You can set up a firstperson controller at design-time or at runtime by:

[...]
 
  protected
    FInputCtrl : TGorillaInputController;
    FFirstPersonCtrl : TGorillaFirstPersonController;
 
[...]
 
uses
  Gorilla.Controller.Input.Types,
  Gorilla.Controller.Input.Character,
  Gorilla.Controller.Input.FirstPerson;
 
[...]
 
FInputCtrl := TGorillaInputController.Create(Self);
FInputCtrl.Supported := [TGorillaInputDeviceType.Keyboard, TGorillaInputDeviceType.Mouse];
FInputCtrl.Enabled := true;
 
FFirstPersonCtrl := TGorillaFirstPersonController.Create(FViewport);
FFirstPersonCtrl.Parent := FViewport;
FFirstPersonCtrl.InputController := FInputCtrl;
FFirstPersonCtrl.Camera := FCamera;

You have some properties to optimize or configure your specific character movement:

The TGorillaThirdPersonController is an extension of the TGorillaFirstPersonController but changes camera movement. It's the typical character controller when having a character model with a top down look by camera.

[...]
 
  protected
    FInputCtrl : TGorillaInputController;
    FThirdPersonCtrl : TGorillaThirdPersonController;
 
[...]
 
uses
  Gorilla.Controller.Input.Types,
  Gorilla.Controller.Input.Character,
  Gorilla.Controller.Input.ThirdPerson;
 
[...]
 
FInputCtrl := TGorillaInputController.Create(Self);
FInputCtrl.Supported := [TGorillaInputDeviceType.Keyboard, TGorillaInputDeviceType.Mouse];
FInputCtrl.Enabled := true;
 
FThirdPersonCtrl := TGorillaThirdPersonController.Create(FViewport);
FThirdPersonCtrl.Parent := FViewport;
FThirdPersonCtrl.InputController := FInputCtrl;
FThirdPersonCtrl.Camera := FCamera;

It's usual to handle different things during character controlling. So you'd like to check for special positions in 3D space and execute actions when getting triggered. Or you like to playback sounds on specific states or refer to a sound-map.

The following components are allowed to link to a character controller:

• TGorillaTriggerPointManager
• TGorillaAudioManagerController
• TGorillaAnimationController

A TGorillaPhysicsCharacterController is a helper layer to manage physics engine, character controller and animation controller. The component handles all the complex management of collision detection and animation playback of a model on basis of a firstperson/thirdperson character controller. Without any programming it's possible to implement a game-typical character controlling, where animations switched automatically on different interactions. On top there is physics collision detection (capsule collider).

Besides easy-to-drop designtime handling, you can setup a physics character controller at runtime.

  [...]
 
  FAssetsManager : TGorillaAssetsManager;
  FMainPackage : TGorillaAssetsPackage;
 
  FPhysics : TGorillaPhysicsSystem;
  FAudioManager : TGorillaFMODAudioManager;
 
  FCharacter : TGorillaModel;
  FPhysCtrl : TGorillaPhysicsCharacterController;
  FAnimCtrl : TGorillaAnimationController;
  FInputCtrl : TGorillaInputController;
  FThirdPersonCtrl : TGorillaThirdPersonController;
  FAudioCtrl : TGorillaAudioManagerController;    
  FTriggerPoints : TGorillaTriggerPointManager;
 
  [...]
 
procedure TGameWindow.LoadCharacter(const AAssets : String);
var LPath : String;
    j : Integer;
    LLay : TGorillaAnimationTransitionLayer;
    LTP : TGorillaTriggerPoint;
begin
  // setup character assets path
  LPath := AAssets + IncludeTrailingPathDelimiter('mymodel');
 
  // create physics character controller (PCC)
  // a PCC is able to connect a character controller with a physics system
  // because with the terrain a collider was added, so that we can walk
  // with our character on it. the PCC will automatically add a capsule collider
  // for collision detection
  FPhysCtrl := TGorillaPhysicsCharacterController.Create(FViewport);
  FPhysCtrl.Parent := FViewport;
  // here we can control the gravity - default value = 25
  FPhysCtrl.GravityScale := 3;
 
  // create character model
  // this will just be a visual instance for our character
  // the controlling will be done by the physics character controller and the
  // third person character controller
  FCharacter := TGorillaModel.LoadNewModelFromFile(FPhysCtrl, FMainPackage,
        LPath + 'mymodel.dae', []);
  FCharacter.Parent := FPhysCtrl;
  // we don't want to interact with the model - so we deactivate any raycast tests.
  FCharacter.SetHitTestValue(false);
  // we always want to see our character, so we disable frustum culling check
  // nevertheless this should not be necessary
  FCharacter.FrustumCullingCheck := false;
  // position character model inside of PCC capsule collider (may be obsolete - depending on your model)
  FCharacter.RotationAngle.Point := Point3D(-180, 90, 0);
  FCharacter.Position.Point := Point3D(0, 8, 0);
  FCharacter.Scale.Point := Point3D(0.75, 0.75, 0.75);
 
  // load all animations used by animation controller
  FCharacter.AddAnimationFromFile(LPath + 'mymodel-idle.dae');
  FCharacter.AddAnimationFromFile(LPath + 'mymodel-walk-forward.dae');
  FCharacter.AddAnimationFromFile(LPath + 'mymodel-walk-backwards.dae');
  FCharacter.AddAnimationFromFile(LPath + 'mymodel-walk-left.dae');
  FCharacter.AddAnimationFromFile(LPath + 'mymodel-walk-right.dae');
  FCharacter.AddAnimationFromFile(LPath + 'mymodel-run-forward.dae');
  FCharacter.AddAnimationFromFile(LPath + 'mymodel-run-backwards.dae');
  FCharacter.AddAnimationFromFile(LPath + 'mymodel-run-left.dae');
  FCharacter.AddAnimationFromFile(LPath + 'mymodel-run-right.dae');
 
  [...]
 
  // we start the first animation in our model - this should be the basis animation
  // inside of the first model file.
  if Assigned(FCharacter.AnimationManager) and Assigned(FCharacter.AnimationManager.Current) then
    FCharacter.AnimationManager.Current.Start();
 
  // animation controller setup
  // create animation controller for handling animation transitions
  // animation transitions define how to switch from one animation to another
  // and which inputs / hotkeys are triggering
  FAnimCtrl := TGorillaAnimationController.Create(FViewport);
  // link the model to the animation controller, to apply animation transitions to
  FAnimCtrl.Model := FCharacter;
 
  // add all defined animation transitions
  LLay := FAnimCtrl.AddLayer('WalkingAnimations');
  LLay.AddTransition('idle-forward > walk-forward', 'mymodel-idle.dae', 'mymodel-walk-forward.dae', true, KeyboardMoveForward, [fpMoving], tmImmediatly);
  LLay.AddTransition('idle-backward > walk-backward', 'mymodel-idle.dae', 'mymodel-walk-backward.dae', true, KeyboardMoveBackward, [fpMoving], tmImmediatly);
  [...]
 
  // set the default animation to be played at the beginning
  FAnimCtrl.DefaultAnimation := 'mymodel-idle.dae'; // the filename of your idle animation
 
  // create an audio manager controller to automatically playback sounds on
  // specific hotkey actions
  FAudioCtrl := TGorillaAudioManagerController.Create(Self);
  FAudioCtrl.AudioManager := Self.FAudioManager;
  FAudioCtrl.AddHotKeyMapping('RUN_FORWARD',  SOUND_RUN,
        TGorillaCharacterControllerHotKey.KeyboardMoveForward, [fpMoving,fpBoost]);
  FAudioCtrl.AddHotKeyMapping('RUN_BACKWARD', SOUND_RUN,
        TGorillaCharacterControllerHotKey.KeyboardMoveBackward, [fpMoving,fpBoost]);
  FAudioCtrl.AddHotKeyMapping('WALK_FORWARD',  SOUND_WALK,
        TGorillaCharacterControllerHotKey.KeyboardMoveForward, [fpMoving]);
  FAudioCtrl.AddHotKeyMapping('WALK_BACKWARD', SOUND_WALK,
        TGorillaCharacterControllerHotKey.KeyboardMoveBackward, [fpMoving]);
 
  // create a trigger points manager and some coordinates to be triggered
  FTriggerPoints := TGorillaTriggerPointManager.Create(Self);
  // we don't want to check against camera, but againts the character model
  FTriggerPoints.RelatedControl := FCharacter;
  FTriggerPoints.Enabled := true;
 
  // wheel #1 trigger point
  LTP := FTriggerPoints.AddTriggerPoint('Wheel1', Point3D(-10, 0, 10), 0.25, 30);
  LTP.LookInDirection := false;
  LTP.Kind := TGorillaTriggerPointKind.StaticTriggerPoint;
  LTP.Data := TValue.From<String>('Press [E] to rotate wheel #1');
  LTP.Tag  := 1;
  LTP.OnTriggered := DoOnWheelTriggered;
  LTP.OnUnTriggered := DoOnWheelUnTriggered;
 
  // wheel #2 trigger point
  LTP := FTriggerPoints.AddTriggerPoint('Wheel2', Point3D(15, 0, -20), 0.25, 30);
  LTP.LookInDirection := false;
  LTP.Kind := TGorillaTriggerPointKind.StaticTriggerPoint;
  LTP.Data := TValue.From<String>('Press [E] to rotate wheel #2');
  LTP.Tag  := 2;
  LTP.OnTriggered := DoOnWheelTriggered;
  LTP.OnUnTriggered := DoOnWheelUnTriggered;
 
  // position the physics controller in 3D physics space - we let the capsule
  // collider drop from -75.0 onto the terrain.
  FPhysCtrl.Position.Point := Point3D(0, -5, 0);
  // link physics controller with character
  FPhysCtrl.Model := FCharacter;
  // resize the capsule collider for better scaled size regarding the scene size
  FPhysCtrl.SetSize(6, 16, 6);
 
  // create a third-person controller
  // this is the basic input handler for characters
  // this will control movement depending on inputs (by the input controller)
  FThirdPersonCtrl := TGorillaThirdPersonController.Create(FPhysCtrl);
  // attach the character controller to the physics character controller (PCC)
  // so it can automatically move it on interaction
  FThirdPersonCtrl.Parent := FPhysCtrl;
  // link the camera to the controller for automatic camera movement
  FThirdPersonCtrl.Camera := FCamera;
  // link the input controller to process all keyboard inputs, to let the
  // character move, jump or whatever
  FThirdPersonCtrl.InputController := FInputCtrl;
  // link the audio manager controller for automatic sound playback on hotkeys
  FThirdPersonCtrl.AudioManagerController := FAudioCtrl;
  // link triggerpoints manager for auto-detection of game coordinates
  FThirdPersonCtrl.TriggerPoints := FTriggerPoints;
 
  // deactivate default behaviour, because we're attaching the character controller
  // to the physics character controller and the physics system
  // we need to deactivate to allow physics system interaction with the character
  FThirdPersonCtrl.UseDefaultMovement := false;
  // reduce default speed, because of large scene scale
  FThirdPersonCtrl.Speed := 15;
 
  // set camera position a bit more far away for better optics
  FCamera.Position.Point := Point3D(25, 0, -20);
  FCamera.Target := FCharacter;
 
  // link animation controller to physics character controller (PCC)
  // the PCC will then automatically dispatch all input events to the animation
  // controller to playback the correct animation transition.
  FPhysCtrl.AnimationController := FAnimCtrl;
  // link the physics system to PCC, to interact with physics world (terrain and objects)
  FPhysCtrl.Physics := FPhysics;
  // link the character controller to PCC, to let the PCC know, what to control.
  FPhysCtrl.Controller := FThirdPersonCtrl;
end;    

Since the latest version of Gorilla3D (v0.8.3.1995) we support kinematic character movement. While previous versions worked completely on physics computation, the latest change added a more stable way.

The true physics collision detection for characters works, but has bad sideeffects. The most serious problem was stuttering characters which bounced off the terrain. Also it was impossible to “climb” up steep hills because physics always dragged you down again. Even if this is more realistic, the usability was horrible for classic character movement.

So in the latest component state the “UseRayCasting” property is activated. This changes the character controller from a dynamic rigid body to a kinematic body. Here we now cast a ray to detect the current position on objects instead of letting physics do the job. Nevertheless interaction with static or dynamic objects is still available.

Remark: In case you need the old behaviour, just switch “UseRayCasting” to FALSE.

Control you raycast-movement by some properties like Slop, RayDirection and RayOffset. Especially the slopping value allows you to control f.e. the max. height of stairs to be able to walk.

Next step: Prefabs